> I am not getting different symbols for groups.
First, you might want to read an article that describes the interaction between ATTRPRIORITY, CYCLEATTRS, and STYLEATTRS in ODS graphics. It might be that what you are seeing (or what you want to see) requires that you understand how these options interact.
It sounds like you might want to use ATTRPRIORITY=NONE, which enables the symbol to automatically change for different groups.
Since we don't have your data, let's use data that we all have. The following creates some data for this example that (hopefully!) is similar to yours:
data Out;
set sashelp.stocks(keep=Stock Date Open where=(Date<'01JAN1991'd));
rename date=Time Open=mean;
run;
proc sort data=Out;
by Time Stock;
run;
/* write spline predictor to OUT2 data set in the PRED variable */
proc glmselect data=Out;
effect spl = spline(Time / basis=bspline knotmethod=equal(9));
class Stock;
model mean = spl | stock / selection=none;
output out=out2 pred=pred;
run;
Now let's graph the data. The following sets ATTRPRIORITY=NONE and lets the symbols, colors, and line styles change according to the ODS style.
ods graphics / AttrPriority=NONE;
proc sgplot data=Out2;
scatter y=mean x=time /group=Stock;
series y=pred x=time / group=Stock;
run;
The output is below. Note that the colors, symbols, and line patterns are different for all groups.
If you want to override the default colors or symbols or patterns, you can use the STYLEATTRS statement, as Paige suggested. You can override 1, 2, or all three attributes. In the following, I set all line patterns to SOLID, but specify colors and patterns for the markers and lines:
ods graphics / AttrPriority=NONE;
proc sgplot data=Out2;
styleattrs datalinepatterns=(solid)
datacontrastcolors=(SteelBlue DarkGreen DarkRed)
datasymbols=(CircleFilled TriangleFilled X);
scatter y=mean x=time /group=Stock markerattrs=( size=6 );
series y=pred x=time / group=Stock;
run;
Please read the article and study the examples. Hope this helps!
... View more
